jmail 发邮件代码

Jmail发邮件代码,2005-6-2版
<%
Dim SendStat
SendStat = Jmail("Dove.163@163.com","Test Jmail","Just a test!","US-ASCII","text/plain")
Response.Write SendStat
%>
<%
'——————————————————————–
Function Jmail(mailTo,mailTopic,mailBody,mailCharset,mailContentType)
'——————————————————————–
'JMail
'——————————————————————–
'入口参数:
'    mailTo 收件人email地址
'    mailTopic 邮件主题
'    mailBody 邮件正文(内容)
'    mailCharset 邮件字符集,例如GB2312或US-ASCII
'    mailContentType 邮件正文格式,例如text/plain或text/html
'返回值:
'    字符串,发送成功后返回OK,不成功返回错误信息
'使用方法:
'    1)设置好常量,即以Const开头的变量
'    2)使用类似如下代码发信
'Dim SendStat
'SendStat = Jmail("aa@163.com","测试Jmail","这是一封<br/>测试信!","GB2312","text/html")
'Response.Write SendStat
'作者:
'    午夜狂龙(Madpolice) madpolice_dong@hotmail.com 2005年6月2日版
'——————————————————————–

'***************根据需要设置常量开始*****************
Dim ConstFromNameCn,ConstFromNameEn,ConstFrom,ConstMailDomain,ConstMailServerUserName,ConstMailServerPassword

ConstFromNameCn = ""'发信人中文姓名(发中文邮件的时候使用),例如‘张三’
ConstFromNameEn = ""'发信人英文姓名(发英文邮件的时候使用),例如‘zhangsan’
ConstFrom = ""'发信人邮件地址,例如‘Shakerd@163.com’
ConstMailDomain = ""'smtp服务器地址,例如smtp.163.com
ConstMailServerUserName = ""'smtp服务器的信箱登陆名,例如‘zhangsan’。注意要与发信人邮件地址一致!
ConstMailServerPassword = ""'smtp服务器的信箱登陆密码
'***************根据需要设置常量结束*****************

'—————————–以下内容无需改动——————————
On Error Resume Next
Dim myJmail
Set myJmail = Server.CreateObject("JMail.Message")
myJmail.Logging = True'记录日志
myJmail.ISOEncodeHeaders = False'邮件头不使用ISO-8859-1编码
myJmail.ContentTransferEncoding = "base64"'邮件编码设为base64
myJmail.AddHeader "Priority","3"'添加邮件头,不要改动!
myJmail.AddHeader "MSMail-Priority","Normal"'添加邮件头,不要改动!
myJmail.AddHeader "Mailer","Microsoft Outlook Express 6.00.2800.1437"'添加邮件头,不要改动!
myJmail.AddHeader "MimeOLE","Produced By Microsoft MimeOLE V6.00.2800.1441"'添加邮件头,不要改动!
myJmail.Charset = mailCharset
myJmail.ContentType = mailContentType

If UCase(mailCharset) = "GB2312" Then
myJmail.FromName = ConstFromNameCn
Else
myJmail.FromName = ConstFromNameEn
End If

myJmail.From = ConstFrom
myJmail.Subject = mailTopic
myJmail.Body = mailBody
myJmail.AddRecipient mailTo
myJmail.MailDomain = ConstMailDomain
myJmail.MailServerUserName = ConstMailServerUserName
myJmail.MailServerPassword = ConstMailServerPassword
myJmail.Send ConstMailDomain
myJmail.Close
Set myJmail=nothing

If Err Then
Jmail=Err.Description
Err.Clear
Else
Jmail="OK"
End If

On Error Goto 0
End Function
'——————————————————————–
%>

说明:更多的信息请参考Jmail说明,我想这已经足够用的了。

(1)Body(信件正文) : 字符串

如:JMail.Body = "这里可以是用户填写的表单内容,可以取自From。"

(2)Charset(字符集,缺省为"US-ASCII") : 字符串

如:JMail.Charset = "US-ASCII"

(3)ContentTransferEncoding : 字符串

指定内容传送时的编码方式,缺省是"Quoted-Printable"
如:JMail.ContentTransferEncoding = "base64"

(4)ContentType(信件的contentype. 缺省是"text/plain") : 字符串

如果你以HTML格式发送邮件, 改为"text/html"即可。
如:JMail.ContentType = "text/html"

(5)Encoding : 字符串

设置附件编码方式(缺省是"base64)。 可以选择使用的是"base64", "uuencode" or "quoted-printable"
如:JMail.Encoding = "base64"

(6)Log(Jmail创建的日志,前提loging属性设置为true,见下面) : 字符串

如:使用Response.Write( JMail.Log )语句列出日志信息。

(7)Logging(是否使用日志) : 布尔型

如:JMail.Logging = true

(8)Recipients : 字符串

只读属性,返回所有收件人
如:Response.Write( "" + JMail.Recipients + "" );

(9)ReplyTo(指定别的回信地址) : 字符串

如:JMail.ReplyTo = "renwang@163.com"

(10)Sender( 发件人的邮件地址) : 字符串

如:JMail.Sender = "renwang@163.com"

(11)SenderName(发件人的姓名) : 字符串

如:JMail.SenderName = "renwang"

(12)ServerAddress(邮件服务器的地址) : 字符串

你可以指定多个服务器,用分号点开。可以指定端口号。
如果serverAddress保持空白,JMail会尝试远程邮件服务器,然后直接发送到服务器上去。
如:JMail.ServerAddress = "mail.263.net.cn"

(13)Subject(设定邮件的标题,可以取自From。):字符串
如:JMail.Subject = "客户反馈表单"

(14)添加文件附件到邮件
如:JMail.AddAttachment( "c:\anyfile.zip" )

(15)AddCustomAttachment( FileName, Data )

添加自定义附件.
如:JMail.AddCustomAttachment( "anyfile.txt", "Contents of file" );

(16)AddHeader( Header, Value )

添加用户定义的信件标头。
如:JMail.AddHeader( "Originating-IP","192.168.10.10" );

(17)AddRecipient(收件人):字符串

如:JMail.AddRecipient( "info@dimac.net" );

(18)AddRecipientBCC( Email ),密件收件人:

如:JMail.AddRecipientBCC( "renwang@163.com" );

(19)AddRecipientCC( Email ) ,抄送收件人:

如:JMail.AddRecipientCC( "anone@mailhost.com" )

(20)AddURLAttachment( URL, 文档名)

下载并添加一个来自url的附件. 第二个参数"文档名", 用来指定信件收到后的文件名。
如:JMail.AddURLAttachment( "http://www.fuo.cc/perl/files/jmail.zip", "jmail" )

(21)AppendBodyFromFile( 文件名) ,将文件作为信件正文:

如:JMail.AppendBodyFromFile( "c:\an
yfile.txt" )

(22)AppendText( Text )

追加信件的正文内容,比如增加问候语或者其它信息。
如:JMail.AppendText( "欢迎访问本站!" )

(23)Close() ,强制JMail关闭缓冲的与邮件服务器的连接:
如:JMail.Close()

(24)Execute() ,执行邮件的发送

如:JMail.Execute()
jmail发邮件代码
<%
Set msg = Server.CreateObject("JMail.Message")
msg.silent = true
msg.Logging = true
msg.Charset = "gb2312"
msg.MailServerUserName = "*****@126.com" ''输入smtp服务器验证登陆名 (邮局中任何一个用户的Email地址)
msg.MailServerPassword = "*****" ''输入smtp服务器验证密码 (用户Email帐号对应的密码)
msg.From ="*****@126.com"' Request.Form("email") ''发件人Email
msg.FromName = "小灰"'Request.Form("name") ''发件人姓名
msg.AddRecipient "*****@163.com" ''收件人Email
msg.Subject = "信件主题"'Request.Form("subject") ''信件主题
msg.Body = "正文"'Request.Form("body") ''正文
'msg.addattachment(server.mappath("new.txt"))
msg.Send ("smtp.126.com") ''smtp服务器地址(企业邮局地址)
set msg = nothing
response.write("发送成功!")
%>

Share

留下评论